* See here: https://dataverse.harvard.edu/dataset.xhtml?persistentId=doi:10.7910/DVN/C8AAVB
* Use the dataset CCES14_UMA_OUTPUT_Aug2015_vmMay2022.dta
* First run the code in the WhatsinaNamereplicationdofileMay2022.do file.

* Check about missingness

sum skindvpre black latino asian nativeamerican other female  age education partyid ideology DMV nflsophindex sportsint  sportsmediaatt nativeracialresentment washfan PercentNative

* Distribution of responses to the measures of resentment against Native Americans

tab  UMA344A UMA344B, mi
tab1 UMA344A UMA344B, mi

* Consistently positive responses about Native Americans

tab UMA344A UMA344B if (UMA344A==1 | UMA344A==2) & (UMA344B==4 | UMA344B==5)
di 582/1500 // 38.8% positive for both

* Negative responses about Native Americans

tab UMA344A UMA344B if (UMA344A==4 | UMA344A==5) | (UMA344B==1 | UMA344B==2), mi
di 294/1500 // 19.6% negative for at least one

tab UMA344A UMA344B if (UMA344A==4 | UMA344A==5) & (UMA344B==1 | UMA344B==2), mi
di  84/1500 // 19.6% negative for at least one

* Footnote

codebook UMA339
recode   UMA339 (4/5=1) (1/3=0), gen(disOFF)
tab      UMA339 disOFF, mi

svyset [pw=weight]

     prop disOFF if (UMA344A==1 | UMA344A==2) & (UMA344B==4 | UMA344B==5) // positive both
svy: prop disOFF if (UMA344A==1 | UMA344A==2) & (UMA344B==4 | UMA344B==5) // positive both

codebook UMA345_1

     prop disOFF if UMA345_1==100 
svy: prop disOFF if UMA345_1==100 

     prop disOFF if (UMA344A==1 | UMA344A==2) & (UMA344B==4 | UMA344B==5) & UMA345_1==100 
svy: prop disOFF if (UMA344A==1 | UMA344A==2) & (UMA344B==4 | UMA344B==5) & UMA345_1==100 

     prop disOFF if (UMA344A==1             ) & (             UMA344B==5) & UMA345_1==100 
svy: prop disOFF if (UMA344A==1             ) & (             UMA344B==5) & UMA345_1==100 

* Building the measure of resentment against Native Americans

codebook UMA344A
recode   UMA344A (6=.), gen(rr1)
replace  rr1 = rr1 - 1
codebook UMA344B
recode   UMA344B (6=.), gen(rr2)
replace  rr2 = 5 - rr2
sum      rr1 rr2

gen nativeRRall = rr1 + rr2
tab nativeRRall

sum nativeRRall
gen nativeRRall01 = (nativeRRall - r(min))/(r(max)-r(min))
sum nativeRRall01

* Check against Sharrow et al. 

svy: reg skindvpre black latino asian nativeamerican other female  age education correctpartyid7 ideology DMV nflsophindex sportsint  sportsmediaatt     nativeRRall01      washfan PercentNative

* Regression with the full sample

reg skindvpre black latino asian nativeamerican other female  age education correctpartyid7 ideology DMV nflsophindex sportsint  sportsmediaatt     nativeRRall01      washfan PercentNative
reg skindvpre nativeRRall01

* Regression removing consistently positive responses about Native Americans

drop if (UMA344A==1 | UMA344A==2) & (UMA344B==4 | UMA344B==5)

gen nativeRRnop = rr1 + rr2
tab nativeRRnop

sum nativeRRnop
gen nativeRRnop01 = (nativeRRnop - r(min))/(r(max)-r(min))
sum nativeRRnop01
tab UMA344A UMA344B if nativeRRnop01!=.
tab UMA344A UMA344B if nativeRRnop01==0
tab UMA344A UMA344B if nativeRRnop01==1

reg skindvpre black latino asian nativeamerican other female  age education correctpartyid7 ideology DMV nflsophindex sportsint  sportsmediaatt     nativeRRnop01      washfan PercentNative
reg skindvpre nativeRRnop01