// Open the cumulative ANES time series file

use "anes_timeseries_cdf.dta"

// Racial resentment

tab1 VCF9039 VCF9040 VCF9041 VCF9042
recode VCF9039 VCF9040 VCF9041 VCF9042 (8=.)
tab1 VCF9039 VCF9040 VCF9041 VCF9042
pwcorr VCF9039 VCF9040 VCF9041 VCF9042
gen RR4 = VCF9039 - VCF9040 - VCF9041 + VCF9042

factor VCF9039 VCF9040 VCF9041 VCF9042, pcf
predict RRfactor
pwcorr RR4 RRfactor

// White

tab VCF0105a
recode VCF0105a (2/7=0), gen(Rwhite)
tab VCF0105a Rwhite, mi

// Male

tab VCF0104
recode VCF0104 (2=0) (3=.), gen(male)
tab VCF0104 male, mi

// Age

tab VCF0101
gen age = VCF0101
tab age, nol

// Education

tab VCF0140a, mi
recode VCF0140a (1/2=1) (3/4=2) (5=3) (6=4) (7=5), gen(educ5)
tab VCF0140a educ5, mi

// Unemployed

tab VCF0116
recode VCF0116 (1/2 5/8=0) (4=1), gen(unemployed)
tab VCF0116 unemployed, mi

recode VCF0116 (1=0) (2/8=1), gen(unemployed2)
tab VCF0116 unemployed2, mi

// Married

tab VCF0147
recode VCF0147 (2/7=0), gen(married)
tab VCF0147 married, mi

// Class

tab VCF0148
recode VCF0148 (0/3=0) (4/7=1), gen(class2)
tab VCF0148 class2, mi

// Income

tab VCF0114
gen income = VCF0114
tab income, nol

// Conservative

tab VCF0803
recode VCF0803 (9=.), gen(consv)
tab VCF0803 consv, mi

recode VCF0803 (9=4), gen(consvMI)
tab VCF0803 consvMI, mi

// Waves (2000, 2004, 2012)

tab VCF0004
gen wave = VCF0004
tab wave, mi

// Weights for the full sample

svyset [pw=VCF0009z]

svy: reg RR4 i.male age       ib4.educ5 i.unemployed  i.married i.class2   income   consv ib2008.wave if Rwhite==1 & (wave>=2000 & wave<=2012)
svy: reg RR4 i.male age       ib4.educ5 i.unemployed2 i.married i.class2   income   consv ib2008.wave if Rwhite==1 & (wave>=2000 & wave<=2012)

svy: reg RR4 i.male i.VCF0102 ib4.educ5 i.unemployed2 i.married i.class2 i.income i.consv ib2008.wave if Rwhite==1 & (wave>=2000 & wave<=2012)

svy: reg RR4                                                                              ib2008.wave if Rwhite==1 & (wave>=2000 & wave<=2012)

sum age income consv

// Weights for the face-to-face sample

svyset [pw=VCF0009x]

svy: reg RR4 i.male age ib4.educ5 i.unemployed  i.married i.class2 income consv ib2008.wave if Rwhite==1 & (wave>=2000 & wave<=2012)

svy: reg RR4 i.VCF0104 i.VCF0102 ib4.VCF0140a i.VCF0116 i.VCF0147 i.VCF0148 i.VCF0114 i.VCF0803 ib2008.wave if Rwhite==1 & (wave>=2000 & wave<=2012)
svy: reg RR4 i.VCF0104 i.VCF0102 ib4.VCF0140a i.VCF0116 i.VCF0147 i.VCF0148 i.VCF0114           ib2008.wave if Rwhite==1 & (wave>=2000 & wave<=2012)

svy: reg RR4 i.VCF0104 i.VCF0102 ib4.VCF0140a i.VCF0116 i.VCF0147 i.VCF0148 i.VCF0114 i.VCF0803 ib2008.wave if Rwhite==1 & (wave>=2000 & wave<=2012)
svy: reg RR4                                                                                    ib2008.wave if Rwhite==1 & (wave>=2000 & wave<=2012)
svy: reg RR4 i.VCF0104 i.VCF0102                                                                ib2008.wave if Rwhite==1 & (wave>=2000 & wave<=2012)

// Including more recent years, compared to 2004

svy: reg RR4 i.VCF0104 i.VCF0102                                                                ib2004.wave if Rwhite==1
svy: reg RR4 i.male age ib4.educ5 i.unemployed  i.married i.class2 income consv                 ib2004.wave if Rwhite==1