* [1] Codebook

codebook q14 female treatment2 q31_1 q31_2 q31_3 q31_4

* [2] Replicate Model 1 Table S3 from Gillooly et al 2021

recode q14 (1=5 "A great deal") (2=4 "A lot") (3=3 "A moderate amount") (4=2 "A little") (5=1 "Not at all"), gen(q14recode)
tab q14recode

gen quant = (q31_1 + q31_2) / 2
gen qual  = (q31_3 + q31_4) / 2

ologit q14recode i.treatment2##i.female quant qual

* [3] Remove the post-treatment controls

ologit q14recode i.treatment2##i.female

* [4] Limit the analysis to male respondents to test for the "backlash"

ologit q14recode treatment2 if female==0
ologit q14recode treatment2 if female==0, robust
reg    q14recode treatment2 if female==0
reg    q14recode treatment2 if female==0, robust

tab q14recode
recode q14recode (1/3=0 "Low") (4/5=1 "High"), gen(q14binary)
tab q14binary

tab q14binary treatment2 if female==0, chi2
prtest q14binary if female==0, by(treatment2)

* [5] Check whether any individual controls were sufficient to reduce the p-value

ologit q14recode treatment2 q31_1 if female==0, robust // *
ologit q14recode treatment2 q31_2 if female==0, robust
ologit q14recode treatment2 q31_3 if female==0, robust
ologit q14recode treatment2 q31_4 if female==0, robust

* [6] Did the treatment affect responses to items used in the controls, among male respondents?

ologit q31_1 treatment2 if female==0, robust
ologit q31_2 treatment2 if female==0, robust
ologit q31_3 treatment2 if female==0, robust
ologit q31_4 treatment2 if female==0, robust