*****************************************************************************************
** LJZ analysis for Peyton and Huber 2021 JOP
** https://dataverse.harvard.edu/dataset.xhtml?persistentId=doi:10.7910/DVN/1Y2DLT
*****************************************************************************************

*****************************************************************************************
** Get sample sizes for non-White respondents:
*****************************************************************************************

// Run Peyton and Huber Stata code lines 14 through 60. Then...

sum responder_id if dem_racewhite==1
di 18450/738
sum responder_id if dem_racewhite==0
di 4325/25
sum responder_id if dem_racewhite==.
di 500/25

clear all

*****************************************************************************************
** Analysis using only White respondents:
*****************************************************************************************

// Run Peyton and Huber Stata code lines 11 through 60. Then...

*****************************************************************************************
** Test whether racial resentment or explicit prejudice better captured discrimination
*****************************************************************************************

reg accept_offer i.offer_amount i.round black_proposer if dem_racewhite==1 & symbolic_binary==1
estimates store RR

reg accept_offer i.offer_amount i.round black_proposer if dem_racewhite==1 & overt_binary==1
estimates store EP

suest RR EP, robust cluster(responder_id)
test [EP_mean]black_proposer = [RR_mean]black_proposer
lincom [EP_mean]black_proposer - [RR_mean]black_proposer

reg accept_offer i.offer_amount i.round black_proposer if dem_racewhite==1 & symbolic_binary==1, robust cluster(responder_id) // to check the suest estimates
reg accept_offer i.offer_amount i.round black_proposer if dem_racewhite==1 & overt_binary==1 , robust cluster(responder_id) // to check the suest estimates

*****************************************************************************************
** Separate category for respondents who rated Whites lower than Blacks on net
*****************************************************************************************

gen WB = (dem_lazy_white - dem_lazy_black) + (dem_unint_white - dem_unint_black) + (dem_untrst_white - dem_untrst_black) + (dem_viol_white - dem_viol_black)
tab WB
tab WB if overt_binary==1
tab WB if overt_binary==0
recode WB (-100/-1=1) (0=2) (1/100=3), gen(WB3)
label define WB3 1 "[1] Rated Whites > Blacks" 2 "[2] Rated Whites = Blacks" 3 "[3] Rated Whites < Blacks"
label values WB3 WB3
tab WB3

*****************************************************************************************
** Compare to Peyton and Huber 2021 measure
*****************************************************************************************

tab WB3 overt_binary

*****************************************************************************************
** Analysis for each level of WB3
*****************************************************************************************

reg accept_offer i.offer_amount i.round black_proposer if WB3==1, robust cluster(responder_id)
reg accept_offer i.offer_amount i.round black_proposer if WB3==2, robust cluster(responder_id)
reg accept_offer i.offer_amount i.round black_proposer if WB3==3, robust cluster(responder_id)

*****************************************************************************************
** Check for differences
*****************************************************************************************

reg accept_offer i.offer_amount i.round black_proposer##ib2.WB3, robust cluster(responder_id)